class PlanoVR {
//
private var ruta:MovieClip;
private var clip:MovieClip;
private var marco:MovieClip;
private var mascara:MovieClip;
private var listener:Object;
private var prof:Number;
private var x:Number;
private var y:Number;
private var width:Number;
private var height:Number;
private var grosor:Number;
private var color:Number;
private var velocidad:Number;
private var aceleracion:Number;
//
//--CONSTRUCTOR------------------------------------
public function PlanoVR(queRuta:MovieClip, queClip:String) {
ruta = queRuta;
prof = ruta.getNextHighestDepth();
clip = ruta.clip = ruta.createEmptyMovieClip("plano", prof);
clip.attachMovie(queClip, queClip, 1);
listener = new Object();
//-- variables default -------
x = clip.x = 0;
y = clip.y = 0;
width = clip.width = 320;
height = clip.height = 240;
grosor = 1;
color = 0x000000;
velocidad = 15;
aceleracion = 0.15;
//-- inis --------------------
iniPosicion();
iniMascara();
iniMarco();
iniEvents();
}
//--INIS-----------------------------------------
private function iniPosicion() {
clip._x = x;
clip._y = y;
}
//--------------------------------------------------
private function iniMascara() {
prof = ruta.getNextHighestDepth();
mascara = ruta.createEmptyMovieClip("mask_mc", prof);
mascara.beginFill(0xFF0000);
mascara.lineStyle(1, 0x000000, 100);
mascara.moveTo(x, y);
mascara.lineTo(x + width, y);
mascara.lineTo(x + width, y + height);
mascara.lineTo(x, y + height);
mascara.lineTo(x, y);
mascara.endFill();
clip.setMask(mascara);
}
//--------------------------------------------------
private function iniMarco() {
prof = ruta.getNextHighestDepth();
marco = ruta.createEmptyMovieClip("marco_mc", prof);
marco.lineStyle(grosor, color, 100);
marco.moveTo(x, y);
marco.lineTo(x + width, y);
marco.lineTo(x + width, y + height);
marco.lineTo(x, y + height);
marco.lineTo(x, y);
}
//--------------------------------------------------
private function iniEvents() {
clip.velocidad = velocidad;
clip.aceleracion = aceleracion;
var plano:MovieClip = clip;
var mouseIsDown:Boolean = false;
//
listener.onMouseDown = function() {
mouseIsDown = true;
//controlamos que se esta dentro del area de la pano
if (_xmouse > plano.x & _xmouse < (plano.x + plano.width) & _ymouse > plano.y & _ymouse < (plano.y + plano.height)) {
plano.onEnterFrame = function() {
this.point2x = _xmouse;
this.point2y = _ymouse;
this.velx = (this.point2x - this.point1x) / this.velocidad * -1;
this.vely = (this.point2y - this.point1y) / this.velocidad * -1 / 2;
plano._x += plano.velx;
plano._y += plano.vely;
controlaTopes();
};
plano.point1x = _xmouse;
plano.point1y = _ymouse;
}
};
listener.onMouseUp = function() {
mouseIsDown = false;
movimientoInercia(plano);
};
listener.onMouseMove = function() {
//controlamos que se esta dentro del area de la pano
if (_xmouse > plano.x & _xmouse < (plano.x + plano.width) & _ymouse > plano.y & _ymouse < (plano.y + plano.height)) {
if (mouseIsDown == false) {
if (_xmouse > plano.x & _xmouse < (plano.x + plano.width / 4)) {
//-- izquierda
plano.onEnterFrame = movimientoAutoH;
plano.point1x = plano.x + plano.width / 4;
} else if (_xmouse > (plano.x + plano.width - plano.width / 4) & _xmouse < (plano.x + plano.width)) {
//-- derecha
plano.onEnterFrame = movimientoAutoH;
plano.point1x = plano.x + plano.width - (plano.width / 4);
} else if (_ymouse > plano.y & _ymouse < (plano.y + plano.height / 4)) {
//-- arriba
plano.onEnterFrame = movimientoAutoV;
plano.point1y = plano.y + (plano.height / 4);
} else if (_ymouse > (plano.y + plano.height - plano.height / 4) & _ymouse < (plano.y + plano.height)) {
//-- abajo
plano.onEnterFrame = movimientoAutoV;
plano.point1y = plano.y + plano.height - (plano.height / 4);
} else {
//estamos fuera del area roll
movimientoInercia(plano);
}
}
} else {
//estamos fuera de la pano
movimientoInercia(plano);
}
};
Mouse.addListener(listener);
//
function controlaTopes() {
if (plano._x > plano.x) {
plano._x = plano.x;
} else if (plano._x < (plano.x - (plano._width - plano.width))) {
plano._x = plano.x - (plano._width - plano.width);
}
if (plano._y > plano.y) {
plano._y = plano.y;
} else if (plano._y < (plano.y - (plano._height - plano.height))) {
plano._y = plano.y - (plano._height - plano.height);
}
}
function movimientoInercia(quePano) {
var plano:MovieClip = quePano;
plano.onEnterFrame = function() {
var ac:Number = plano.velx * plano.aceleracion;
plano.velx -= ac;
plano._x += plano.velx;
if (ac < 0.01 & ac > -0.01) {
delete plano.onEnterFrame;
}
controlaTopes();
};
}
function movimientoAutoH() {
this.point2x = _xmouse;
this.velx = (this.point2x - this.point1x) / this.velocidad * -1;
plano._x += plano.velx;
controlaTopes();
}
function movimientoAutoV() {
this.point2y = _ymouse;
this.vely = (this.point2y - this.point1y) / this.velocidad * -1;
plano._y += plano.vely;
controlaTopes();
}
}
//end iniEvents
//--------------------------------------------------
private function update() {
iniPosicion();
removeMovieClip(mascara);
iniMascara();
removeMovieClip(marco);
iniMarco();
iniEvents();
}
//
//--SETTERS-----------------------------------------
public function setPosicion(queX:Number, queY:Number) {
x = clip.x = queX;
y = clip.y = queY;
update();
}
//--------------------------------------------------
public function setDimension(queW:Number, queH:Number) {
width = clip.width = queW;
height = clip.height = queH;
update();
}
//--------------------------------------------------
public function setMarco(queGrosor, queColor:Number) {
grosor = queGrosor;
color = queColor;
update();
}
//--------------------------------------------------
public function setVelocidad(queVelocidad:Number) {
velocidad = clip.velocidad = queVelocidad;
update();
}
//--------------------------------------------------
public function setAceleracion(queAceleracion:Number) {
aceleracion = clip.aceleracion = queAceleracion;
update();
}
//--------------------------------------------------
public function setPlano(queClip:String) {
removeMovieClip(clip.plano);
clip.attachMovie(queClip, queClip, 1);
update();
}
//--------------------------------------------------
public function clear() {
removeMovieClip(clip);
removeMovieClip(mascara);
}
//--------------------------------------------------
//--------------------------------------------------
}